******************************************************
* The Aggregated Consequences of Motivated Reasoning *
* Matt Lebo                                          *
* July 5, 2007                                       *
* Forthcoming at Political Psychology                *
******************************************************

end 1
calendar 1953 2 12
allocate 2005:04
open data presapsheet.xls
data(format=xls,org=columns) / year nmonth monthtot national rep dem ind $
 CPI changeCPI pveinf nveinf rpveinf rnveinf dpveinf dnveinf $
 unemp changeunemp pveunemp nveunemp rpveunemp rnveunemp dpveunemp dnveunemp reppres $
 honey second third fourth E1 E2 E3 E4 E5 E6 E7	E8 K1 K2 K3 K4 K5 K6 K7	J1 J2 J3 J4 J5 $
 J6 J7 J8 J9 J10 J11 J12 N1 N2 N3 N4 N5	N6 N7 N8 F1 F2 F3 C1 C2 C3 C4 C5 C6 C7 C8 C9 C10 $
 R1 R2 R3 R4 R5 R6 R7 R8 R9 R10 R11 B1 B2 B3 B4 B5 B6 B7 B8 L1 L2 L3 L4 L5 L6 L7 L8 L9 L10 L11 $
 L12 L13 L14 L15 W1 W2 W3 W4 W5 rpevents rnevents dpevents dnevents rhoney dhoney $
 ehoney khoney jhoney nhoney fhoney choney rhoney bhoney lhoney whoney

set partgap = abs(rep-dem)
* source files needed for various procedures used.  See Extima.com for these.
source bjident.src
source sbc.src
source(noecho) kpss.src
source(noecho) dfunit.src
source(noecho) rgser.src
source(noecho) fif.src
* difference key DVs before testing for level of integration
difference national / natd
difference rep / repd
difference dem / demd
difference ind / indd
difference partgap / partgapd
* get level of d for differenced DVs
@rgser repd
@rgser demd
@rgser indd
@rgser natd
@rgser partgapd
* fractionally difference DVs by their value of Robinson's d (on the differenced series)
@fif(d=-.10) repd / repdf
@fif(d=-.15) demd / demdf
@fif(d=-.25) indd / inddf
@fif(d=-.20) natd / natdf
@fif(d=-.33) partgapd / partgapdf

* Get some useful statistics for the paper and Table 1
SET INPARTY = rep
SET INPARTY 1961:01 1969:01 = dem
SET INPARTY 1977:02 1980:12 = dem
SET INPARTY 1993:01 2001:01 = dem
SET OUTPARTY = dem
SET OUTPARTY 1961:01 1969:01 = rep
SET OUTPARTY 1977:02 1980:12 = rep
SET OUTPARTY 1993:01 2001:01 = rep
table / inparty outparty ind rep dem indd repd demd
* Variances: INPARTY= 149.2; OUTPARTY= 207.3; IND=173.3
* difference IVs -- but these weren't used since the variables were all created to be stationary
difference pveinf / pveinfd
difference nveinf / nveinfd
difference pveunemp / pveunempd
difference nveunemp / nveunempd
difference rpveinf / rpveinfd
difference rnveinf / rnveinfd
difference rpveunemp / rpveunempd
difference rnveunemp / rnveunempd
difference dpveinf / dpveinfd
difference dnveinf / dnveinfd
difference dpveunemp / dpveunempd
difference dnveunemp / dnveunempd
difference rpevents / rpeventsd
difference rnevents / rneventsd
difference dpevents / dpeventsd
difference dnevents / dneventsd
difference honey / honeyd
difference rhoney / rhoneyd
difference dhoney / dhoneyd
difference k4 / k4d
difference n7 / n7d
difference c8 / c8d
difference b1 / b1d
difference b2 / b2d
difference l11 / l11d
difference w1 / w1d
difference w3 / w3d
difference e6 / e6d
difference j2 / j2d
difference r4 / r4d
difference r10 / r10d
difference l9 / l9d
difference l13 / l13d
difference unemp / unempd
difference cpi / cpid
difference reppres / reppresd
difference ehoney / ehoneyd
difference khoney / khoneyd
difference jhoney / jhoneyd
difference nhoney / nhoneyd
difference fhoney / fhoneyd
difference choney / choneyd
difference rhoney / rhoneyd
difference bhoney / bhoneyd
difference lhoney / lhoneyd
difference whoney / whoneyd

* A couple interventions left out of the dataset
SET IKETOUR = T>=1959:12.AND.T<=1960:01
difference IKETOUR / IKETOURD
SET IKEDOC = T>=1957:04.AND.T<=1957:04
difference IKEDOC / IKEDOCD
set khoney2 = T==1961:01
difference khoney2 / khoney2d
set nhoney2 = T==1969:02
difference nhoney2 / nhoney2d
set rhoney2 = T==1981:01
difference rhoney2 / rhoney2d
set khoney3 = khoney + khoney2
set nhoney3 = nhoney + nhoney2
set rhoney3 = rhoney + rhoney2
***************************************************
* Analysis for Tables 2,3,4
smpl 1955:01 2005:04
@dfunit changecpi
@dfunit changeunemp

@dfunit rpveinf
@dfunit rnveinf
@dfunit rpveunemp
@dfunit rnveunemp
@dfunit dpveinf
@dfunit dnveinf
@dfunit dpveunemp
@dfunit dnveunemp
* Create separate ECM's for each equation
linreg rep / recm
# constant CPI{0 to 3} unemp{0 to 3}
difference recm / recmd
@rgser recmd
@fif(d=-.11) recmd / recmdf

linreg dem / decm
# constant CPI{0 to 3} unemp{0 to 3}
difference decm / decmd
@rgser decmd
@fif(d=-.20) decmd / decmdf

linreg ind / iecm
# constant CPI{0 to 3} unemp{0 to 3}
difference iecm / iecmd
@rgser iecmd
@fif(d=-.26) iecmd / iecmdf

* Creates Tables 2,3,4
equation REPEQ repdf
# constant recmdf{1} repdf{1} rpveinf{1 to 3} rnveinf{1 to 3} rpveunemp{1 to 3} rnveunemp{1 to 3} $
 dpveinf{1 to 3} dnveinf{1 to 3} dpveunemp{1 to 3} dnveunemp{1 to 3} $
 rpevents rnevents dpevents dnevents k4 n7d c8d b1d l13 w1{0 to 1} w3 $
 khoney3 jhoney nhoney3 fhoney choney rhoney3 lhoney{0 to 1} whoney{0 to 1}

equation DEMEQ demdf
# constant decmdf{1} demdf{1} rpveinf{1 to 3} rnveinf{1 to 3} rpveunemp{1 to 3} rnveunemp{1 to 3} $
 dpveinf{1 to 3} dnveinf{1 to 3} dpveunemp{1 to 3} dnveunemp{1 to 3} $
 rpevents rnevents dpevents dnevents e6 k4 n7d c8 b1d b2d w1{0 to 1} w3 $
 khoney nhoney fhoney choney rhoney lhoney{0 to 1} whoney{0 to 1} iketourd ikedocd

equation INDEQ inddf
# constant iecmdf{1} inddf{1} rpveinf{1 to 3} rnveinf{1 to 3} rpveunemp{1 to 3} rnveunemp{1 to 3} $
 dpveinf{1 to 3} dnveinf{1 to 3} dpveunemp{1 to 3} dnveunemp{1 to 3} $
 rpevents rnevents dpevents dnevents k4 n7d c8d b1d l9d w1{0 to 1} w3 $
 khoney jhoney nhoney fhoney choney rhoney lhoney whoney
* these three lines estimate the equations separately
linreg(equation=REPEQ) repdf / repres
linreg(equation=DEMEQ) demdf / demres
linreg(equation=INDEQ) inddf / indres
* But we want to do them together
sur(vcv) 3
# REPEQ
# DEMEQ
# INDEQ

*** F tests for Republican equation
test
# 4 5 6
# 0.0 0.0 0.0
test
# 7 8 9
# 0.0 0.0 0.0
test
# 10 11 12
# 0.0 0.0 0.0
test
# 13 14 15
# 0.0 0.0 0.0

test
# 16 17 18
# 0.0 0.0 0.0
test
# 19 20 21
# 0.0 0.0 0.0
test
# 22 23 24
# 0.0 0.0 0.0
test
# 25 26 27
# 0.0 0.0 0.0

*** F tests for Democratic equation
test
# 53 54 55
# 0.0 0.0 0.0
test
# 56 57 58
# 0.0 0.0 0.0
test
# 59 60 61
# 0.0 0.0 0.0
test
# 62 63 64
# 0.0 0.0 0.0

test
# 65 66 67
# 0.0 0.0 0.0
test
# 68 69 70
# 0.0 0.0 0.0
test
# 71 72 73
# 0.0 0.0 0.0
test
# 74 75 76
# 0.0 0.0 0.0

*** F Test for Independent equation
test
# 104 105 106
# 0.0 0.0 0.0
test
# 107 108 109
# 0.0 0.0 0.0
test
# 110 111 112
# 0.0 0.0 0.0
test
# 113 114 115
# 0.0 0.0 0.0

test
# 116 117 118
# 0.0 0.0 0.0
test
# 119 120 121
# 0.0 0.0 0.0
test
# 122 123 124
# 0.0 0.0 0.0
test
# 125 126 127
# 0.0 0.0 0.0

* DIAGNOSTINCS
* ARCH
set ressqr = repres**2
linreg(noprint) ressqr
# constant ressqr{1}
compute chistat=%nobs*%rsquared
cdf chisqr chistat 1
* Qstats
correlate(qstats,number=24,span=12,dfc=3) repres
correlate(qstats,number=24,span=12,dfc=3) demres
correlate(qstats,number=24,span=12,dfc=3) indres
* Durbin's H and B-G.
linreg REPDF
# constant recmdf{1} repdf{1} rpveinf{1 to 3} rnveinf{1 to 3} rpveunemp{1 to 3} rnveunemp{1 to 3} $
 dpveinf{1 to 3} dnveinf{1 to 3} dpveunemp{1 to 3} dnveunemp{1 to 3} $
 rpevents rnevents dpevents dnevents k4 n7d c8d b1d l13 w1{0 to 1} w3 $
 khoney3 jhoney nhoney3 fhoney choney rhoney3 lhoney{0 to 1} whoney{0 to 1}
compute h=sqrt(%nobs)*%rho/sqrt(1-%nobs*%stderrs(2)**2)
cdf(title='Durbins h test') normal h
linreg %resids
# constant recmdf{1} repdf{1} rpveinf{1 to 3} rnveinf{1 to 3} rpveunemp{1 to 3} rnveunemp{1 to 3} $
 dpveinf{1 to 3} dnveinf{1 to 3} dpveunemp{1 to 3} dnveunemp{1 to 3} $
 rpevents rnevents dpevents dnevents k4 n7d c8d b1d l13 w1{0 to 1} w3 $
 khoney3 jhoney nhoney3 fhoney choney rhoney3 lhoney{0 to 1} whoney{0 to 1} %resids{1}
cdf(title='Breusch-Godfrey SC test') chisqr %trsq 1

linreg DEMDF
# constant decmdf{1} demdf{1} rpveinf{1 to 3} rnveinf{1 to 3} rpveunemp{1 to 3} rnveunemp{1 to 3} $
 dpveinf{1 to 3} dnveinf{1 to 3} dpveunemp{1 to 3} dnveunemp{1 to 3} $
 rpevents rnevents dpevents dnevents e6 k4 n7d c8 b1d b2d w1{0 to 1} w3 $
 khoney nhoney fhoney choney rhoney lhoney{0 to 1} whoney{0 to 1} iketourd ikedocd
linreg %resids
# constant decmdf{1} demdf{1} rpveinf{1 to 3} rnveinf{1 to 3} rpveunemp{1 to 3} rnveunemp{1 to 3} $
 dpveinf{1 to 3} dnveinf{1 to 3} dpveunemp{1 to 3} dnveunemp{1 to 3} $
 rpevents rnevents dpevents dnevents e6 k4 n7d c8 b1d b2d w1{0 to 1} w3 $
 khoney nhoney fhoney choney rhoney lhoney{0 to 1} whoney{0 to 1} iketourd ikedocd %resids{1}
cdf(title='Breusch-Godfrey SC test') chisqr %trsq 1
linreg INDDF
# constant iecmdf{1} inddf{1} rpveinf{1 to 3} rnveinf{1 to 3} rpveunemp{1 to 3} rnveunemp{1 to 3} $
 dpveinf{1 to 3} dnveinf{1 to 3} dpveunemp{1 to 3} dnveunemp{1 to 3} $
 rpevents rnevents dpevents dnevents k4 n7d c8d b1d l9d w1{0 to 1} w3 $
 khoney jhoney nhoney fhoney choney rhoney lhoney whoney
linreg %resids
# constant iecmdf{1} inddf{1} rpveinf{1 to 3} rnveinf{1 to 3} rpveunemp{1 to 3} rnveunemp{1 to 3} $
 dpveinf{1 to 3} dnveinf{1 to 3} dpveunemp{1 to 3} dnveunemp{1 to 3} $
 rpevents rnevents dpevents dnevents k4 n7d c8d b1d l9d w1{0 to 1} w3 $
 khoney jhoney nhoney fhoney choney rhoney lhoney whoney %resids{1}
cdf(title='Breusch-Godfrey SC test') chisqr %trsq 1

compute h=sqrt(%nobs)*%rho/sqrt(1-%nobs*%stderrs(2)**2)
cdf(title='Durbins h test') normal h
linreg(equation=repeq) repdf / repres
compute denom=1-%nobs*%seesq*%xx(2,2)
if denom>0
  compute h=%rho*sqrt(%nobs/denom)
else
  compute h=0.0
end if
cdf normal h
linreg(equation=DEMEQ) demdf / demres
compute denom=1-%nobs*%seesq*%xx(2,2)
if denom>0
  compute h=%rho*sqrt(%nobs/denom)
else
  compute h=0.0
end if
cdf normal h
linreg(equation=INDEQ) inddf / indres
compute denom=1-%nobs*%seesq*%xx(2,2)
if denom>0
  compute h=%rho*sqrt(%nobs/denom)
else
  compute h=0.0
end if
cdf normal h

**************************************************
** Partisan Gap
smpl 1953:03 2005:04
SET IKETOUR = T>=1959:12.AND.T<=1960:01
difference IKETOUR / IKETOURD
@dfunit changecpi
@dfunit changeunemp
@dfunit pveunemp
@dfunit nveunemp
@dfunit pveinf
@dfunit nveinf
difference partgap / partgapd
@rgser partgapd
@fif(d=-.33) partgapd / partgapdf

linreg partgap / gapecm
# constant CPI{0 to 3} unemp{0 to 3}
difference gapecm / gapecmd
@rgser gapecmd
@fif(d=-.35) gapecmd / gapecmdf

* TABLE 5
linreg partgapdf 1953:03 2005:04 gapres
# constant gapecmdf{1} pveunemp{1 to 3} nveunemp{1 to 3} pveinf{1 to 3} nveinf{1 to 3} $
 rpevents rnevents dpevents dnevents iketourd $
 k4{1 2} e6 j2 b1d b2d l13 w1{0 to 1} w3 khoney{0 2} jhoney{0 to 1} nhoney{0 to 1} $
 fhoney choney rhoney{0 1} bhoney{0 1} lhoney whoney

correlate(qstats,number=24,span=12,dfc=3) gapres
* F tests for Table 5
test
# 3 4 5
# 0.0 0.0 0.0
test
# 6 7 8
# 0.0 0.0 0.0
test
# 9 10 11
# 0.0 0.0 0.0
test
# 12 13 14
# 0.0 0.0 0.0

*** FIGURE 2
smpl 1955:01 2005:04
set dempres = t>=1961:01.and.t<=1969:01.or.t>=1977:01.and.t<=1981:01.or.t>=1993:01.and.t<=2001:01
SPGRAPH(vfields=2,hfields=1,HEADER='Figure 2: Presidential Approval and the Partisan Gap')
graph(shading=dempres,header='Republican and Democrat Approval',VLABEL='Approval Rating',HLABEL='Year',klabels=||'Republicans','Democrats'||,key=below) 2
# REP
# DEM
graph(shading=dempres,header='The Partisan Gap',subheader='Absolute Difference Between Republican and Democrat Approval', $
 VLABEL='Partisan Gap',HLABEL='Year',klabels=||'Partisan Gap'||,key=below) 1
# partgap
spgraph(done)

*** FIGURE 3
graph(shading=dempres,header='Figure 3: Presidential Approval among Independents', $
 VLABEL='Approval Rating',HLABEL='Year') 1
# IND